100 "A" CLEAR : CLS :D=256:C=&F9D3: DIM B$(9)*1: WAIT 0
  101 RESTORE 102: FOR I=0 TO 27: READ A: POKE &F9D3+I,A: NEXT I:A=0
  102 DATA 16,249,208,0,2,130,24,16,52,0,132,83,144,0,9,53,16,249,198,144,25,16,52
  103 DATA 0,2,16,82,55
  104 CLS : PRINT "Hex-Monitor (C)J.Schulze": PRINT "Disp(D) Print(P) Quit(Q)"
  105 IF  INKEY$ ="" THEN 105
  106 T$= INKEY$ : IF T$="D" THEN 139
  107 IF T$="P" THEN 114
  108 IF T$="Q" CLS : END 
  109 GOTO 105
  110 CLS : PRINT "Adresse: "; HEX (A);: CURSOR 8: INPUT A
  111 CURSOR 24: PRINT "Bank <8: "; STR$ B;: CURSOR 32: INPUT B
  112 B= ABS  INT B: IF B>7 THEN 111
  113 CLS : RETURN 
  114 CLS : PRINT "15-PIN (1)  11-PIN (2)": PRINT "Zurueck(Z)  Quit(Q)"
  115 IF  INKEY$ ="" THEN 115
  116 T$= INKEY$ : IF T$="1" THEN 121
  117 IF T$="2" THEN 132
  118 IF T$="Z" THEN  CLS : GOTO 104
  119 IF T$="Q" CLS : END 
  120 GOTO 115
  121 CLS : CLOSE : CONSOLE 51: ERASE A$: DIM A$(0)*18
  122 PRINT "OPEN$="; OPEN$ : INPUT "OPEN  ";A$(0): OPEN A$(0): ERASE A$: GOTO 124
  123 OPEN 
  124 CLS : INPUT "Anfang ";A,"Ende ";E,"Bank ";B
  125 B= ABS  INT B: IF B>7 OR A>=E THEN 124
  126 FOR I=A TO E STEP 10: GOSUB 156: LPRINT  USING ; STR$ B; USING "#####"; HEX (I);: USING "###"
  127 FOR J=&F9C6 TO &F9CF: LPRINT  HEX ( PEEK J);: IF  PEEK J<32 OR ( PEEK J>126 AND  PEEK J<245) OR  PEEK J>252 POKE J,32
  128 NEXT J: USING 
  129 LPRINT "->";B$(0);B$(1);B$(2);B$(3);B$(4);B$(5);B$(6);B$(7);B$(8);B$(9)
  130 IF  INKEY$ ="" NEXT I: GOTO 104
  131 I=E: NEXT I: CLOSE : GOTO 104
  132 CLS : INPUT "Anfang ";A,"Ende ";E,"Bank ";B
  133 FOR I=A TO E STEP 4: GOSUB 156: LPRINT  USING ; STR$ B; USING "#####"; HEX (A);: USING "###"
  134 FOR J=&F9C6 TO &F9C9: LPRINT  HEX ( PEEK J);: IF  PEEK J<32 OR ( PEEK J>126 AND  PEEK J<245) OR  PEEK J>252 POKE J,32
  135 NEXT J: USING 
  136 LPRINT "->";B$(0);B$(1);B$(2);B$(3)
  137 IF  INKEY$ ="" NEXT I: GOTO 104
  138 I=E: NEXT I: GOTO 104
  139 CLS : GOSUB 110
  140 CURSOR 0,1: PRINT "(P)   (A)    (B:"+ STR$ B+")  (Q)";
  141 CURSOR 0: GOSUB 155: PRINT  USING "#####"; HEX (A);: USING "###"
  142 FOR J=&F9C6 TO &F9C9: PRINT  HEX ( PEEK J);: IF  PEEK J<32 OR ( PEEK J>126 AND  PEEK J<245) OR  PEEK J>252 POKE J,32
  143 NEXT J: USING 
  144 PRINT "->";B$(0);B$(1);B$(2);B$(3)
  145 IF  INKEY$ ="" THEN 145
  146 T= ASC  INKEY$ : IF T=5 LET A=A+4: GOTO 141
  147 IF T=4 LET A=A-4: GOTO 141
  148 IF T=14 LET A=A+1: GOTO 141
  149 IF T=15 LET A=A-1: GOTO 141
  150 IF T=65 THEN 139
  151 IF T=66 CURSOR 0,1: PRINT "                        ": GOSUB 111: GOTO 140
  152 IF T=80 THEN 114
  153 IF T=81 CLS : END 
  154 GOTO 145
  155 H= INT (A/D):L=A-H*D: POKE &F9D0,L,H,B: CALL C: RETURN 
  156 H= INT (I/D):L=I-H*D: POKE &F9D0,L,H,B: CALL C: RETURN