1000 "M" CLEAR : RANDOM : INPUT "Anz.Buchst(<=26):";F: IF F>26 OR F<2 THEN 1000
 1001 INPUT "Anz.Stellen(<11):";N:N=N-1: IF N>10 OR N<2 THEN 1001
 1002 INPUT "Anz.Versuche:";V,"Doppelte(J/N)";Z$
 1003 PAUSE "Benutze   A->"+ CHR$ (F+64)
 1004 DIM A(N),B(N),D$(0)*(N+8): IF  ASC Z$=78 GOSUB 1017: GOTO 1006
 1005 FOR I=0 TO N:A(I)= RND F+64: NEXT I
 1006 PAUSE "Deine Tips": FOR T=1 TO V: PAUSE T;"Versuch"
 1007 INPUT D$(0): IF  LEN (D$(0))<>N+1 PAUSE "Bitte "+ STR$ (N+1)+" Zeichen!": GOTO 1007
 1008 FOR I=0 TO N:B(I)= ASC  MID$ (D$(0),I+1,1): NEXT I:S=0,W=0
 1009 FOR I=0 TO N: FOR P=0 TO N: IF I=P AND A(I)=B(P) LET S=S+1:B(P)=0:P=N: GOTO 1011
 1010 IF A(I)=B(P) AND A(P)<>B(P) AND A(I)<>B(I) LET W=W+1:B(P)=0:P=N
 1011 NEXT P: NEXT I: IF S=N+1 PRINT "ready beim ";T;"Versuch!": GOTO 1015
 1012 PRINT D$(0)+" "+ STR$ S+" S"+"/"+ STR$ W+" W"
 1013 NEXT T:D$(0)= CHR$ A(0): FOR I=1 TO N:D$(0)=D$(0)+ CHR$ A(I): NEXT I
 1014 PAUSE "Kein Erfolg, Du Niete!": PRINT "Loesung:";D$(0)
 1015 INPUT "Nochmal? ";Z$: IF  ASC Z$=78 END 
 1016 GOTO 1000
 1017 FOR I=0 TO N:A(I)= RND F+64: FOR J=0 TO I: IF I=J THEN 1019
 1018 IF A(I)=A(J) LET J=I:I=I-1
 1019 NEXT J: NEXT I: RETURN